C'est maintenant une macro complémentaire utilisable depuis n'importe quel classeur. Cette macro, nous ne la verrons pas en détail ici, elle est trop compliquée. Elle permet :
- MFC sur formats de cellule (par valeurs et formules)
- MFC déportée (Saisie d'une cellule et MFC sur d'autres)
- MFC Sonores (envoie un fichier Wave selon une valeur)
- MFC Images (Affiche une image selon une valeur)
- MFC sur Commentaires (Affiche un commentaire et image selon valeur)
De plus il est possible :
- D'avoir plusieures Feuille de MFC différentes
- De définir différentes plages de MFC
Versions avant 2007
Menu Outils / Macros complémentaire
Bouton Parcourir
Recherchez la macro complémentaire fournie Gw_mfc_V7.3.xla
Tout valider
Les formules ne vont pas vraiment compliquer la méthode. Au lieu de mettre des valeurs, dans les cellules A2 à Axx, nous y mettrons des formules qui renvoient VRAI ou FAUX. La macro prendra le format du 1er VRAI trouvé sinon, prendra le format par défaut de la cellule A1
Le fichier exemple fourni montre son utilisation.
Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
If Target.FormatConditions.Count = 0 Then Exit Sub ' Controle si la cellule contient des Formatages conditionnels
Dim fc As FormatCondition, ws As Worksheet
Dim i As Integer, fmt As Range
Set ws = Sheets("MFC")
For Each fc In Target.FormatConditions ' Je passe en revue toutes les MFC
If UCase(Left(fc.Formula1, 6)) = "=MAMFC" Then ' Je teste en Majuscule si c'est la mienne
Set fmt = ws.Range("A1") ' Mise en place du Format par défaut
Application.EnableEvents = False ' Je deconnecte l'interception d'évennement (pour ne pas relancer cette macro)
fmt.Value = Target.Value ' Mise en place de la valeur en A1 de la feuille MFC
ws.Calculate ' Force le calcul de la feuille MFC (Le paramétrage de calcul peut être en manuel)
Application.EnableEvents = True ' Je reconnecte l'interception d'évennement
For i = 2 To ws.Range("A65536").End(xlUp).Row ' Boucle de A2 à Axxx (xxx trouvé en partant de la fin)
If ws.Range("A" & i).Value = True Then
Set fmt = ws.Range("A" & i) ' La valeur étant trouvée ....
Exit For ' je sors de la boucle, inutile de continuer
End If
Next i
Target.Interior.ColorIndex = fmt.Interior.ColorIndex ' Couleur de fond
Target.Font.ColorIndex = fmt.Font.ColorIndex ' Couleur de texte
Target.Font.Bold = fmt.Font.Bold ' Gras
Target.Font.Italic = fmt.Font.Italic ' Italique
Target.Font.Size = fmt.Font.Size ' Taille de caractère
Target.Font.Underline = fmt.Font.Underline ' Sousligné
Target.NumberFormat = fmt.NumberFormat ' Format de la cellule
Target.HorizontalAlignment = fmt.HorizontalAlignment ' Alignement
Target.VerticalAlignment = fmt.VerticalAlignment ' Alignement
End If
Next ' Prochaine MFC
End Sub
Phase 1 : Intégrer le code ci-dessus dans le module ThisWorkBook.
Phase 2 : Créer dans le classeur la feuille MFC avec les formules (faisant référence à la cellule A1) et les formats correspondant en colonne A, tout en reservant A1, cellule de référence pour le format par défaut
Phase 3 : Mettre comme formule dans les MFC des cellules saisies : =MaMfc
La mise en forme conditionnelle par valeur est la plus simple puisque la macro contrôle si la valeur existe et si oui elle applique le format de la cellule trouvée.
Le fichier exemple fourni montre son utilisation.
Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
If Target.FormatConditions.Count = 0 Then Exit Sub ' Controle si la cellule contient des Formatages conditionnels
Dim fc As FormatCondition, ws As Worksheet
Dim i As Integer, fmt As Range
Set ws = Sheets("MFC")
For Each fc In Target.FormatConditions ' Je passe en revue toutes les MFC
If UCase(Left(fc.Formula1, 6)) = "=MAMFC" Then ' Je teste en Majuscule si c'est la mienne
Set fmt = ws.Range("A1") ' Mise en place du Format par défaut
For i = 2 To ws.Range("A65536").End(xlUp).Row ' Boucle de A2 à Axxx (xxx trouvé en partant de la fin)
If ws.Range("A" & i) = Target Then
Set fmt = ws.Range("A" & i) ' La valeur étant trouvée ....
Exit For ' je sors de la boucle, inutile de continuer
End If
Next i
Target.Interior.ColorIndex = fmt.Interior.ColorIndex ' Couleur de fond
Target.Font.ColorIndex = fmt.Font.ColorIndex ' Couleur de texte
Target.Font.Bold = fmt.Font.Bold ' Gras
Target.Font.Italic = fmt.Font.Italic ' Italique
Target.Font.Size = fmt.Font.Size ' Taille de caractère
Target.Font.Underline = fmt.Font.Underline ' Sousligné
Target.NumberFormat = fmt.NumberFormat ' Format de la cellule
Target.HorizontalAlignment = fmt.HorizontalAlignment ' Alignement
Target.VerticalAlignment = fmt.VerticalAlignment ' Alignement
End If
Next ' Prochaine MFC
End Sub
Phase 1 : Intégrer le code ci-dessus dans le module ThisWorkBook.
Phase 2 : Créer dans le classeur la feuille MFC avec les valeurs et les formats correspondant en colonne A, tout en reservant A1, cellule de référence pour le format par défaut
Phase 3 : Mettre comme formule dans les MFC des cellules saisies : =MaMfc
