La concaténation de matices existe déjà dans une macro complémentaire. Non seulement il faut charger en mémoire toute la bibliothèque mais ne pas oublier de la transférer en cas de transfert du classeur sur un autre Pc.
Etant donné le peu de ligne qu'elle comprend, il est plus intéressant de la placer directement dans notre classeur.
Function Matrice_Concatener(valeur As Variant, Optional separator As String = "", Optional vide As Boolean = False) As String
Dim c As Variant
Application.Volatile
For Each c In valeur
If vide = False Then
If c > "" Then
Matrice_Concatener = Matrice_Concatener & c
If separator > "" Then Matrice_Concatener = Matrice_Concatener & separator
End If
Else
Matrice_Concatener = Matrice_Concatener & c
If separator > "" Then Matrice_Concatener = Matrice_Concatener & separator
End If
Next
If separator > "" Then Matrice_Concatener = Left(Matrice_Concatener, Len(Matrice_Concatener) - Len(separator))
End Function
=Matrice_Concatener(Plage; [Separator]; [vide])
Plage : plage à concaténer, peut etre nommée ou issue d'une matice
Separator : Séparateur de valeurs, par défaut pas de séparateur
Vide : Mettre à vrai pour récuperer les valeurs Vides.
(est à Faux par défaut)
Seules les formules Somme, Moyenne, Nb, NbVal sont utilisables sur des plages discontinues ou multifeuille. Somme.Si, Nb.si, Sommeprod ou toute autre formule matricielle sont impossibles à réaliser ou encore totalement illisibles.
Cette fonction sert à créer des matrices à partir de plages discontinues ou à partir de plusieures feuilles, rendant alors possibles et aisés les calculs multifeuilles
Function M_Charge(plage As Range, Optional feuilles As String = "") As Variant
Dim cel As Range, i As Long, j As Integer, tablo() As Variant, tablof() As Variant
Dim f As Integer, feuille1 As String, feuille2 As String
Application.Volatile ' Permet un recalcul automatique
' Définition de la feuille par défaut si aucune feuille n'est mentionnée
If feuilles = "" Then feuilles = ActiveSheet.Name & ":" & ActiveSheet.Name
i = -1
If InStr(feuilles, ",") > 0 Then ' traitement des feuilles non contigues (séparées par des virgules)
While InStr(feuilles, ",") > 0
i = i + 1
ReDim Preserve tablof(i)
tablof(i) = Left(feuilles, InStr(feuilles, ",") - 1)
feuilles = Mid(feuilles, InStr(feuilles, ",") + 1, Len(feuilles) - InStr(feuilles, ","))
Wend
End If
i = i + 1
ReDim Preserve tablof(i)
tablof(i) = feuilles
i = -1
For f = LBound(tablof) To UBound(tablof) ' traite les différent blocs de feuilles
feuilles = tablof(f)
If InStr(feuilles, ":") = 0 Then feuilles = feuilles & ":" & feuilles ' je crée le bloc la feuille est seule
' Récupération de la feuille de début et la feuille de fin
feuille1 = Left(feuilles, InStr(feuilles, ":") - 1)
feuille2 = Right(feuilles, Len(feuilles) - InStr(feuilles, ":"))
' Passage en revue de toutes les feuilles entre Feuille1 et Feuille2
For j = Sheets(feuille1).Index To Sheets(feuille2).Index
For Each cel In plage ' Pour chacune des cellules de la plage
i = i + 1
ReDim Preserve tablo(i) ' J'incrémente la table en cours de création
tablo(i) = Sheets(j).Cells(cel.Row, cel.Column).Value ' Récupélation de la valeur
Next
Next j
Next f
M_Charge = tablo ' Affectation du tableau à la fonction (la matrice est créée)
End Function
=M_Charge(plage; [feuilles])
plage : La plage concernée (elle peut etre nommée)
Feuilles : "Feuil1:Feuil5,Feuil7" Bloc de feuilles à récupérer
(feuilles est optionnel, s'il est omis la feuille active est
concernée)
Cette fonction permet de récupérer 10 critères de formatage d'une cellule. Elle crée une matrice de 1 à 10.
Les criteres :
Ne fonctionne pas sur des Mises en Forme Conditionnelles
Public Function M_Cellule(Target As Range) As Variant
Application.Volatile
Dim tablo(1 To 10) As Variant
tablo(1) = Target.Font.Bold
tablo(2) = Target.Font.ColorIndex
tablo(3) = Target.Font.FontStyle
tablo(4) = Target.Font.Italic
tablo(5) = Target.Font.Strikethrough
tablo(6) = Target.Font.Underline
tablo(7) = Target.Interior.ColorIndex
tablo(8) = Target.Interior.Pattern
tablo(9) = Target.Interior.PatternColorIndex
tablo(10) = Target.NumberFormat
M_Cellule = tablo
End Function
6 - Caractères Soulignés
7 - Couleur de la cellule
8 - Hachurage de la cellule
9 - Couleur des hachures
10 - Format de la cellule
1 - Caractères Gras
2 - Couleur Caratères
3 - Style de fonte
4 - Caractères italiques
5 - Caractères barrés
Cette fonction crée une matrice d'une des caractéristiques d'une plage. pour extraire la caractéristique désirée, elle utilise M_cellule précédemment expliquée. Elle permet donc de nombrer ou sommer des plages de cellules selon la couleur de fond, ou Gras ou Italique... (cf : Format cellule)
Ne fonctionne pas sur des Mises en Forme Conditionnelles
Public Function M_Format(ByVal gw_typ As Integer, plage As Range, Optional feuilles As String = "") As Variant
Dim gw_c As Range, i As Long, j As Integer
Dim tablo() As Variant, maplage As Range
Dim feuille1 As String, feuille2 As String
Application.Volatile
If gw_typ < 1 Or gw_typ > 10 Then trg_mfc_plage = "#ERREUR": Exit Function
i = -1
If feuilles = "" Then feuilles = ActiveSheet.Name & ":" & ActiveSheet.Name
feuille1 = Left(feuilles, InStr(feuilles, ":") - 1)
feuille2 = Right(feuilles, Len(feuilles) - InStr(feuilles, ":"))
For j = ActiveWorkbook.Sheets(feuille1).Index To ActiveWorkbook.Sheets(feuille2).Index
Set maplage = ActiveWorkbook.Sheets(j).Range(plage.Address)
For Each gw_c In maplage
i = i + 1
ReDim Preserve tablo(i)
tablo(i) = M_Cellule(gw_c)(gw_typ)
Next
Next j
M_Format = tablo
End Function
